***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 21, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5518C-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.821
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=940.5  VTO=2.2  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=3.935e11  gamma=1.2)
Rd     d1    d2    0.30m TC=3m,18u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=33  TBV1=4.555e-4   CJO=6.625e-9  M=7.948e-1  VJ=7.726)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.758e-13  N=0.850  RS=12.04u  EG=1.06  TT=20n ikf=5.734e+1)
Rdiode  d1  21    5.080e-7 TC=3.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   7.401e-10
.MODEL     DGD    D(M=2.017   CJO=7.401e-10   VJ=8.739)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    4.464e-9
.ENDS
*$
